View source with formatted comments or as raw
    1/*  Part of SWI-Prolog
    2
    3    Author:        Jan Wielemaker
    4    E-mail:        J.Wielemaker@vu.nl
    5    WWW:           http://www.swi-prolog.org
    6    Copyright (c)  2003-2020, University of Amsterdam
    7                              VU University Amsterdam
    8                              CWI, Amsterdam
    9    All rights reserved.
   10
   11    Redistribution and use in source and binary forms, with or without
   12    modification, are permitted provided that the following conditions
   13    are met:
   14
   15    1. Redistributions of source code must retain the above copyright
   16       notice, this list of conditions and the following disclaimer.
   17
   18    2. Redistributions in binary form must reproduce the above copyright
   19       notice, this list of conditions and the following disclaimer in
   20       the documentation and/or other materials provided with the
   21       distribution.
   22
   23    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
   24    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
   25    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
   26    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
   27    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
   28    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
   29    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
   30    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
   31    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   32    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
   33    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
   34    POSSIBILITY OF SUCH DAMAGE.
   35*/
   36
   37:- module(make,
   38          [ make/0,
   39            make_reload_file/1      % +File
   40          ]).   41:- autoload(library(apply),[maplist/2]).   42:- autoload(library(check),[list_undefined/0,list_void_declarations/0]).   43:- use_module(library(debug),[debug/3]).   44:- autoload(library(lists),[list_to_set/2,member/2]).   45:- autoload(library(option),[merge_options/3]).   46
   47
   48:- set_prolog_flag(generate_debug_info, false).   49
   50/** <module>  Reload modified source files
   51
   52This module provides the SWI-Prolog   `make'  facility that synchronises
   53Prolog internal database after loaded files have been edited.
   54
   55@bug    Dependency tracking is incomplete.  Notably, there is no
   56        dependency tracking if compilation of one module depends
   57        on goal_expansion/2 or term_expansion/2 rules provided by
   58        another.
   59*/
   60
   61:- multifile
   62    prolog:make_hook/2.   63
   64
   65%!  make
   66%
   67%   Reload all source files that have   been changed since they were
   68%   loaded. This predicate peforms the following steps:
   69%
   70%     1. Compute the set of files that need to be reloaded.
   71%     2. Call the hook prolog:make_hook(before, Files)
   72%     3. Reload the files
   73%     4. Call the hook prolog:make_hook(after, Files)
   74%     5. If (4) fails, call list_undefined/0.
   75%
   76%   The hooks are called  with  an  empty   list  if  no  files need
   77%   reloading.
   78
   79make :-
   80    notrace(make_no_trace).
   81
   82make_no_trace :-
   83    '$update_library_index',
   84    findall(File, modified_file(File), Reload0),
   85    list_to_set(Reload0, Reload),
   86    (   prolog:make_hook(before, Reload)
   87    ->  true
   88    ;   true
   89    ),
   90    print_message(silent, make(reload(Reload))),
   91    maplist(make_reload_file, Reload),
   92    print_message(silent, make(done(Reload))),
   93    (   prolog:make_hook(after, Reload)
   94    ->  true
   95    ;   list_undefined,
   96        list_void_declarations
   97    ).
   98
   99%!  modified_file(-File) is nondet.
  100%
  101%   True when File is modified after it has been loaded.
  102%
  103%   (*) A file is considered modified if   the  modification time of the
  104%   file is at least 1ms later that when  it was loaded. The 1ms relaxed
  105%   matching is used to compensate for   inconsistent float handling and
  106%   possible timing jitter.
  107%
  108%   @see https://github.com/SWI-Prolog/swipl-devel/issues/303
  109
  110modified_file(File) :-
  111    source_file_property(Source, modified(Time)),
  112    \+ source_file_property(Source, included_in(_,_)),
  113    Time > 0.0,                     % See source_file/1
  114    (   source_file_property(Source, derived_from(File, LoadTime))
  115    ->  true
  116    ;   File = Source,
  117        LoadTime = Time
  118    ),
  119    (   catch(time_file(File, Modified), _, fail),
  120        Modified - LoadTime > 0.001             % (*)
  121    ->  true
  122    ;   file_includes(Source, Included, IncLoadTime, [Source]),
  123        catch(time_file(Included, Modified), _, fail),
  124        Modified - IncLoadTime > 0.001          % (*)
  125    ->  true
  126    ).
  127
  128file_includes(Source, Included, IncLoadTime, Seen) :-
  129    source_file_property(Source, includes(Included0, IncLoadTime0)),
  130    \+ memberchk(Included0, Seen),
  131    (   Included = Included0,
  132        IncLoadTime = IncLoadTime0
  133    ;   file_includes(Included0, Included, IncLoadTime, [Included0|Seen])
  134    ).
  135
  136%!  make_reload_file(File)
  137%
  138%   Reload file into the proper module.
  139%
  140%   @bug    If modules import each other, we must load them in the
  141%           proper order for import/export dependencies.
  142
  143:- public reload_file/1.                % Used by PDT
  144reload_file(File) :- make_reload_file(File).
  145
  146make_reload_file(File) :-
  147    source_base_name(File, Compile),
  148    findall(M-Opts,
  149            source_file_property(File, load_context(M, _, Opts)),
  150            Modules),
  151    (   Modules = [First-OptsFirst|Rest]
  152    ->  Extra = [ silent(false),
  153                  register(false)
  154                ],
  155        merge_options([if(true)|Extra], OptsFirst, OFirst),
  156        debug(make, 'Make: First load ~q', [load_files(First:Compile, OFirst)]),
  157        load_files(First:Compile, OFirst),
  158        forall(member(Context-Opts, Rest),
  159               ( merge_options([if(not_loaded)|Extra], Opts, O),
  160                 debug(make, 'Make: re-import: ~q',
  161                       [load_files(Context:Compile, O)]),
  162                 load_files(Context:Compile, O)
  163               ))
  164    ;   load_files(user:Compile)
  165    ).
  166
  167source_base_name(File, Compile) :-
  168    file_name_extension(Compile, Ext, File),
  169    user:prolog_file_type(Ext, prolog),
  170    !.
  171source_base_name(File, File).
  172
  173
  174%!  prolog:make_hook(+When, +Files) is semidet.
  175%
  176%   This hook is called by make/0. It   is called with the following
  177%   values for When:
  178%
  179%     - before
  180%     The hook is called before reloading starts. The default
  181%     action is to do nothing.
  182%
  183%     - after
  184%     The hook is called after reloading completed.  The default
  185%     action is to call list_undefined/1 as:
  186%
  187%       ==
  188%       list_undefined([scan(local)]).
  189%       ==
  190%
  191%   The hook can be  used  to   change  program  validation, stop or
  192%   restart services, etc.
  193%
  194%   @arg Files is a list holding the canonical file names of the
  195%        files that need to be reloaded.  This list can be empty.