View source with raw comments or as raw
    1/*  Part of SWI-Prolog
    2
    3    Author:        Jan Wielemaker
    4    E-mail:        J.Wielemaker@vu.nl
    5    WWW:           http://www.swi-prolog.org
    6    Copyright (c)  2007-2020, University of Amsterdam
    7                              VU University Amsterdam
    8                              CWI, Amsterdam
    9    All rights reserved.
   10
   11    Redistribution and use in source and binary forms, with or without
   12    modification, are permitted provided that the following conditions
   13    are met:
   14
   15    1. Redistributions of source code must retain the above copyright
   16       notice, this list of conditions and the following disclaimer.
   17
   18    2. Redistributions in binary form must reproduce the above copyright
   19       notice, this list of conditions and the following disclaimer in
   20       the documentation and/or other materials provided with the
   21       distribution.
   22
   23    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
   24    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
   25    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
   26    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
   27    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
   28    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
   29    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
   30    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
   31    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   32    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
   33    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
   34    POSSIBILITY OF SUCH DAMAGE.
   35*/
   36
   37:- module(thread,
   38          [ concurrent/3,               % +Threads, :Goals, +Options
   39            concurrent_maplist/2,       % :Goal, +List
   40            concurrent_maplist/3,       % :Goal, ?List1, ?List2
   41            concurrent_maplist/4,       % :Goal, ?List1, ?List2, ?List3
   42            first_solution/3,           % -Var, :Goals, +Options
   43
   44            call_in_thread/2            % +Thread, :Goal
   45          ]).   46:- use_module(library(debug)).   47:- use_module(library(error)).   48:- use_module(library(lists)).   49:- use_module(library(apply)).   50:- use_module(library(option)).   51
   52%:- debug(concurrent).
   53
   54:- meta_predicate
   55    concurrent(+, :, +),
   56    concurrent_maplist(1, +),
   57    concurrent_maplist(2, ?, ?),
   58    concurrent_maplist(3, ?, ?, ?),
   59    first_solution(-, :, +),
   60    call_in_thread(+, 0).   61
   62
   63:- predicate_options(concurrent/3, 3,
   64                     [ pass_to(system:thread_create/3, 3)
   65                     ]).   66:- predicate_options(first_solution/3, 3,
   67                     [ on_fail(oneof([stop,continue])),
   68                       on_error(oneof([stop,continue])),
   69                       pass_to(system:thread_create/3, 3)
   70                     ]).

High level thread primitives

This module defines simple to use predicates for running goals concurrently. Where the core multi-threaded API is targeted at communicating long-living threads, the predicates here are defined to run goals concurrently without having to deal with thread creation and maintenance explicitely.

Note that these predicates run goals concurrently and therefore these goals need to be thread-safe. As the predicates in this module also abort branches of the computation that are no longer needed, predicates that have side-effect must act properly. In a nutshell, this has the following consequences:

author
- Jan Wielemaker */
 concurrent(+N, :Goals, Options) is semidet
Run Goals in parallel using N threads. This call blocks until all work has been done. The Goals must be independent. They should not communicate using shared variables or any form of global data. All Goals must be thread-safe.

Execution succeeds if all goals have succeeded. If one goal fails or throws an exception, other workers are abandoned as soon as possible and the entire computation fails or re-throws the exception. Note that if multiple goals fail or raise an error it is not defined which error or failure is reported.

On successful completion, variable bindings are returned. Note however that threads have independent stacks and therefore the goal is copied to the worker thread and the result is copied back to the caller of concurrent/3.

Choosing the right number of threads is not always obvious. Here are some scenarios:

Arguments:
N- Number of worker-threads to create. Using 1, no threads are created. If N is larger than the number of Goals we create exactly as many threads as there are Goals.
Goals- List of callable terms.
Options- Passed to thread_create/3 for creating the workers. Only options changing the stack-sizes can be used. In particular, do not pass the detached or alias options.
See also
- In many cases, concurrent_maplist/2 and friends is easier to program and is tractable to program analysis.
  149concurrent(1, M:List, _) :-
  150    !,
  151    maplist(once_in_module(M), List).
  152concurrent(N, M:List, Options) :-
  153    must_be(positive_integer, N),
  154    must_be(list(callable), List),
  155    length(List, JobCount),
  156    message_queue_create(Done),
  157    message_queue_create(Queue),
  158    WorkerCount is min(N, JobCount),
  159    create_workers(WorkerCount, Queue, Done, Workers, Options),
  160    submit_goals(List, 1, M, Queue, VarList),
  161    forall(between(1, WorkerCount, _),
  162           thread_send_message(Queue, done)),
  163    VT =.. [vars|VarList],
  164    concur_wait(JobCount, Done, VT, cleanup(Workers, Queue),
  165                Result, [], Exitted),
  166    subtract(Workers, Exitted, RemainingWorkers),
  167    concur_cleanup(Result, RemainingWorkers, [Queue, Done]),
  168    (   Result == true
  169    ->  true
  170    ;   Result = false
  171    ->  fail
  172    ;   Result = exception(Error)
  173    ->  throw(Error)
  174    ).
  175
  176once_in_module(M, Goal) :-
  177    call(M:Goal), !.
 submit_goals(+List, +Id0, +Module, +Queue, -Vars) is det
Send all jobs from List to Queue. Each goal is added to Queue as a term goal(Id, Goal, Vars). Vars is unified with a list of lists of free variables appearing in each goal.
  185submit_goals([], _, _, _, []).
  186submit_goals([H|T], I, M, Queue, [Vars|VT]) :-
  187    term_variables(H, Vars),
  188    thread_send_message(Queue, goal(I, M:H, Vars)),
  189    I2 is I + 1,
  190    submit_goals(T, I2, M, Queue, VT).
 concur_wait(+N, +Done:queue, +VT:compound, +Cleanup, -Result, +Exitted0, -Exitted) is semidet
Wait for completion, failure or error.
Arguments:
Exited- List of thread-ids with threads that completed before all work was done.
  201concur_wait(0, _, _, _, true, Exited, Exited) :- !.
  202concur_wait(N, Done, VT, Cleanup, Status, Exitted0, Exitted) :-
  203    debug(concurrent, 'Concurrent: waiting for workers ...', []),
  204    catch(thread_get_message(Done, Exit), Error,
  205          concur_abort(Error, Cleanup, Done, Exitted0)),
  206    debug(concurrent, 'Waiting: received ~p', [Exit]),
  207    (   Exit = done(Id, Vars)
  208    ->  debug(concurrent, 'Concurrent: Job ~p completed with ~p', [Id, Vars]),
  209        arg(Id, VT, Vars),
  210        N2 is N - 1,
  211        concur_wait(N2, Done, VT, Cleanup, Status, Exitted0, Exitted)
  212    ;   Exit = finished(Thread)
  213    ->  thread_join(Thread, JoinStatus),
  214        debug(concurrent, 'Concurrent: waiter ~p joined: ~p',
  215              [Thread, JoinStatus]),
  216        (   JoinStatus == true
  217        ->  concur_wait(N, Done, VT, Cleanup, Status, [Thread|Exitted0], Exitted)
  218        ;   Status = JoinStatus,
  219            Exitted = [Thread|Exitted0]
  220        )
  221    ).
  222
  223concur_abort(Error, cleanup(Workers, Queue), Done, Exitted) :-
  224    debug(concurrent, 'Concurrent: got ~p', [Error]),
  225    subtract(Workers, Exitted, RemainingWorkers),
  226    concur_cleanup(Error, RemainingWorkers, [Queue, Done]),
  227    throw(Error).
  228
  229create_workers(N, Queue, Done, [Id|Ids], Options) :-
  230    N > 0,
  231    !,
  232    thread_create(worker(Queue, Done), Id,
  233                  [ at_exit(thread_send_message(Done, finished(Id)))
  234                  | Options
  235                  ]),
  236    N2 is N - 1,
  237    create_workers(N2, Queue, Done, Ids, Options).
  238create_workers(_, _, _, [], _).
 worker(+WorkQueue, +DoneQueue) is det
Process jobs from WorkQueue and send the results to DoneQueue.
  245worker(Queue, Done) :-
  246    thread_get_message(Queue, Message),
  247    debug(concurrent, 'Worker: received ~p', [Message]),
  248    (   Message = goal(Id, Goal, Vars)
  249    ->  (   Goal
  250        ->  thread_send_message(Done, done(Id, Vars)),
  251            worker(Queue, Done)
  252        )
  253    ;   true
  254    ).
 concur_cleanup(+Result, +Workers:list, +Queues:list) is det
Cleanup the concurrent workers and message queues. If Result is not true, signal all workers to make them stop prematurely. If result is true we assume all workers have been instructed to stop or have stopped themselves.
  264concur_cleanup(Result, Workers, Queues) :-
  265    !,
  266    (   Result == true
  267    ->  true
  268    ;   kill_workers(Workers)
  269    ),
  270    join_all(Workers),
  271    maplist(message_queue_destroy, Queues).
  272
  273kill_workers([]).
  274kill_workers([Id|T]) :-
  275    debug(concurrent, 'Signalling ~w', [Id]),
  276    catch(thread_signal(Id, abort), _, true),
  277    kill_workers(T).
  278
  279join_all([]).
  280join_all([Id|T]) :-
  281    thread_join(Id, _),
  282    join_all(T).
  283
  284
  285                 /*******************************
  286                 *             MAPLIST          *
  287                 *******************************/
 concurrent_maplist(:Goal, +List) is semidet
 concurrent_maplist(:Goal, +List1, +List2) is semidet
 concurrent_maplist(:Goal, +List1, +List2, +List3) is semidet
Concurrent version of maplist/2. This predicate uses concurrent/3, using multiple worker threads. The number of threads is the minimum of the list length and the number of cores available. The number of cores is determined using the prolog flag cpu_count. If this flag is absent or 1 or List has less than two elements, this predicate calls the corresponding maplist/N version using a wrapper based on once/1. Note that all goals are executed as if wrapped in once/1 and therefore these predicates are semidet.

Note that the the overhead of this predicate is considerable and therefore Goal must be fairly expensive before one reaches a speedup.

  306concurrent_maplist(Goal, List) :-
  307    workers(List, WorkerCount),
  308    !,
  309    maplist(ml_goal(Goal), List, Goals),
  310    concurrent(WorkerCount, Goals, []).
  311concurrent_maplist(M:Goal, List) :-
  312    maplist(once_in_module(M, Goal), List).
  313
  314once_in_module(M, Goal, Arg) :-
  315    call(M:Goal, Arg), !.
  316
  317ml_goal(Goal, Elem, call(Goal, Elem)).
  318
  319concurrent_maplist(Goal, List1, List2) :-
  320    same_length(List1, List2),
  321    workers(List1, WorkerCount),
  322    !,
  323    maplist(ml_goal(Goal), List1, List2, Goals),
  324    concurrent(WorkerCount, Goals, []).
  325concurrent_maplist(M:Goal, List1, List2) :-
  326    maplist(once_in_module(M, Goal), List1, List2).
  327
  328once_in_module(M, Goal, Arg1, Arg2) :-
  329    call(M:Goal, Arg1, Arg2), !.
  330
  331ml_goal(Goal, Elem1, Elem2, call(Goal, Elem1, Elem2)).
  332
  333concurrent_maplist(Goal, List1, List2, List3) :-
  334    same_length(List1, List2, List3),
  335    workers(List1, WorkerCount),
  336    !,
  337    maplist(ml_goal(Goal), List1, List2, List3, Goals),
  338    concurrent(WorkerCount, Goals, []).
  339concurrent_maplist(M:Goal, List1, List2, List3) :-
  340    maplist(once_in_module(M, Goal), List1, List2, List3).
  341
  342once_in_module(M, Goal, Arg1, Arg2, Arg3) :-
  343    call(M:Goal, Arg1, Arg2, Arg3), !.
  344
  345ml_goal(Goal, Elem1, Elem2, Elem3, call(Goal, Elem1, Elem2, Elem3)).
  346
  347workers(List, Count) :-
  348    current_prolog_flag(cpu_count, Cores),
  349    Cores > 1,
  350    length(List, Len),
  351    Count is min(Cores,Len),
  352    Count > 1,
  353    !.
  354
  355same_length([], [], []).
  356same_length([_|T1], [_|T2], [_|T3]) :-
  357    same_length(T1, T2, T3).
  358
  359
  360                 /*******************************
  361                 *             FIRST            *
  362                 *******************************/
 first_solution(-X, :Goals, +Options) is semidet
Try alternative solvers concurrently, returning the first answer. In a typical scenario, solving any of the goals in Goals is satisfactory for the application to continue. As soon as one of the tried alternatives is successful, all the others are killed and first_solution/3 succeeds.

For example, if it is unclear whether it is better to search a graph breadth-first or depth-first we can use:

search_graph(Grap, Path) :-
         first_solution(Path, [ breadth_first(Graph, Path),
                                depth_first(Graph, Path)
                              ],
                        []).

Options include thread stack-sizes passed to thread_create, as well as the options on_fail and on_error that specify what to do if a solver fails or triggers an error. By default execution of all solvers is terminated and the result is returned. Sometimes one may wish to continue. One such scenario is if one of the solvers may run out of resources or one of the solvers is known to be incomplete.

on_fail(Action)
If stop (default), terminate all threads and stop with the failure. If continue, keep waiting.
on_error(Action)
As above, re-throwing the error if an error appears.
bug
- first_solution/3 cannot deal with non-determinism. There is no obvious way to fit non-determinism into it. If multiple solutions are needed wrap the solvers in findall/3.
  402first_solution(X, M:List, Options) :-
  403    message_queue_create(Done),
  404    thread_options(Options, ThreadOptions, RestOptions),
  405    length(List, JobCount),
  406    create_solvers(List, M, X, Done, Solvers, ThreadOptions),
  407    wait_for_one(JobCount, Done, Result, RestOptions),
  408    concur_cleanup(kill, Solvers, [Done]),
  409    (   Result = done(_, Var)
  410    ->  X = Var
  411    ;   Result = error(_, Error)
  412    ->  throw(Error)
  413    ).
  414
  415create_solvers([], _, _, _, [], _).
  416create_solvers([H|T], M, X, Done, [Id|IDs], Options) :-
  417    thread_create(solve(M:H, X, Done), Id, Options),
  418    create_solvers(T, M, X, Done, IDs, Options).
  419
  420solve(Goal, Var, Queue) :-
  421    thread_self(Me),
  422    (   catch(Goal, E, true)
  423    ->  (   var(E)
  424        ->  thread_send_message(Queue, done(Me, Var))
  425        ;   thread_send_message(Queue, error(Me, E))
  426        )
  427    ;   thread_send_message(Queue, failed(Me))
  428    ).
  429
  430wait_for_one(0, _, failed, _) :- !.
  431wait_for_one(JobCount, Queue, Result, Options) :-
  432    thread_get_message(Queue, Msg),
  433    LeftCount is JobCount - 1,
  434    (   Msg = done(_, _)
  435    ->  Result = Msg
  436    ;   Msg = failed(_)
  437    ->  (   option(on_fail(stop), Options, stop)
  438        ->  Result = Msg
  439        ;   wait_for_one(LeftCount, Queue, Result, Options)
  440        )
  441    ;   Msg = error(_, _)
  442    ->  (   option(on_error(stop), Options, stop)
  443        ->  Result = Msg
  444        ;   wait_for_one(LeftCount, Queue, Result, Options)
  445        )
  446    ).
 thread_options(+Options, -ThreadOptions, -RestOptions) is det
Split the option list over thread(-size) options and other options.
  454thread_options([], [], []).
  455thread_options([H|T], [H|Th], O) :-
  456    thread_option(H),
  457    !,
  458    thread_options(T, Th, O).
  459thread_options([H|T], Th, [H|O]) :-
  460    thread_options(T, Th, O).
  461
  462thread_option(local(_)).
  463thread_option(global(_)).
  464thread_option(trail(_)).
  465thread_option(argument(_)).
  466thread_option(stack(_)).
 call_in_thread(+Thread, :Goal) is semidet
Run Goal as an interrupt in the context of Thread. This is based on thread_signal/2. If waiting times out, we inject a stop(Reason) exception into Goal. Interrupts can be nested, i.e., it is allowed to run a call_in_thread/2 while the target thread is processing such an interrupt.

This predicate is primarily intended for debugging and inspection tasks.

  480call_in_thread(Thread, Goal) :-
  481    thread_self(Thread),
  482    !,
  483    once(Goal).
  484call_in_thread(Thread, Goal) :-
  485    term_variables(Goal, Vars),
  486    thread_self(Me),
  487    A is random(1 000 000 000),
  488    thread_signal(Thread, run_in_thread(Goal,Vars,A,Me)),
  489    catch(thread_get_message(in_thread(A,Result)),
  490          Error,
  491          forward_exception(Thread, A, Error)),
  492    (   Result = true(Vars)
  493    ->  true
  494    ;   Result = error(Error)
  495    ->  throw(Error)
  496    ;   fail
  497    ).
  498
  499run_in_thread(Goal, Vars, Id, Sender) :-
  500    (   catch_with_backtrace(call(Goal), Error, true)
  501    ->  (   var(Error)
  502        ->  thread_send_message(Sender, in_thread(Id, true(Vars)))
  503        ;   Error = stop(_)
  504        ->  true
  505        ;   thread_send_message(Sender, in_thread(Id, error(Error)))
  506        )
  507    ;   thread_send_message(Sender, in_thread(Id, false))
  508    ).
  509
  510forward_exception(Thread, Id, Error) :-
  511    kill_with(Error, Kill),
  512    thread_signal(Thread, kill_task(Id, Kill)),
  513    throw(Error).
  514
  515kill_with(time_limit_exceeded, stop(time_limit_exceeded)) :-
  516    !.
  517kill_with(_, stop(interrupt)).
  518
  519kill_task(Id, Exception) :-
  520    prolog_current_frame(Frame),
  521    prolog_frame_attribute(Frame, parent_goal,
  522                           run_in_thread(_Goal, _Vars, Id, _Sender)),
  523    !,
  524    throw(Exception).
  525kill_task(_, _)