Did you know ... Search Documentation:
Predicate open/3
Availability:built-in
[ISO]open(+SrcDest, +Mode, --Stream)
Equivalent to open/4 with an empty option list.

Examples

Read all lines to a list

Read all lines to a list

file_lines(File, Lines) :-
    setup_call_cleanup(open(File, read, In),
       stream_lines(In, Lines),
       close(In)).

stream_lines(In, Lines) :-
    read_string(In, _, Str),
    split_string(Str, "\n", "", Lines).

This loads all lines to memory as strings. If we use the Unix dictionary words:

?- file_lines("/usr/share/dict/words", Lines).
Words = ["A", "a", "aa", "aal", "aalii", "aam", "Aani", "aardvark", "aardwolf"|...].
Backtrack over lines in a file

Backtrack over lines in a file

file_line(File, Line) :-
    setup_call_cleanup(open(File, read, In),
        stream_line(In, Line),
        close(In)).

stream_line(In, Line) :-
    repeat,
    (   read_line_to_string(In, Line0),
        Line0 \== end_of_file
    ->  Line0 = Line
    ;   !,
        fail
    ).

This will backtrack over consecutive lines in the input. If we use the Unix dictionary words:

?- file_line("/usr/share/dict/words", Word).
Word = "A" ;
Word = "a" ;
Word = "aa" ;
Word = "aal" ; % and so on

This doesn't load all lines to memory, so it can be used with very large files.

See also
- read_line_to_codes/2 to read to a code list instead of a string
- read_string/5 for more control over the separator and stripping
Tags are associated to your profile if you are logged in|Report abuse
Tags:
  • doc-needs-help
LogicalCaptain said (2020-03-20T13:17:44):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

Question: What does an empty option list assume about the encoding of the file?

According to the page for open/4:

The default encoding for type text is derived from the Prolog flag encoding.
For binary streams the default encoding is octet.
For details on encoding issues, see section encoding.

Under Prolog flag encoding, we read:

Default encoding used for opening files in text mode. The initial value is deduced from the environment.

So I guess, the environment variable LANG is the one which determines the "default encoding".