Did you know ... Search Documentation:
Predicate nb_setarg/3
Availability:built-in
nb_setarg(+Arg, +Term, +Value)
Assigns the Arg-th argument of the compound term Term with the given Value as setarg/3, but on backtracking the assignment is not reversed. If Value is not atomic, it is duplicated using duplicate_term/2. This predicate uses the same technique as nb_setval/2. We therefore refer to the description of nb_setval/2 for details on non-backtrackable assignment of terms. This predicate is compatible with GNU-Prolog setarg(A,T,V,false), removing the type restriction on Value. See also nb_linkarg/3. Below is an example for counting the number of solutions of a goal. Note that this implementation is thread-safe, reentrant and capable of handling exceptions. Realising these features with a traditional implementation based on assert/retract or flag/3 is much more complicated. 
:- meta_predicate
        succeeds_n_times(0, -).

succeeds_n_times(Goal, Times) :-
        Counter = counter(0),
        (   Goal,
            arg(1, Counter, N0),
            N is N0 + 1,
            nb_setarg(1, Counter, N),
            fail
        ;   arg(1, Counter, Times)
        ).
Tag confusing pages with doc-needs-help|Tags are associated to your profile if you are logged in
Tags:
LogicalCaptain said (2020-12-07T14:53:32):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

Beware this little predicate Unexpected result for predicate nb_setarg/3

?-
functor(A, array, 5),
forall(
   arg(Index, A, foo),
   nb_setarg(Index, A, bar)).
A = array(_16050, _16052, _16054, _16056, _16058).

The above is expected as backtracking occurs to before the position where array at position Index is set to foo, rolling back the nb_setarg/3 effect by rolling back the arg/3 effect.

However:

?-
A=array(_,_,_,_,_),
forall(
   arg(Index, A, foo),
   nb_setarg(Index, A, bar)).
A = array(bar, bar, bar, bar, bar).

This is actually a problem with SWI-Prolog (8.3.14). It shouldn't work.

This one doesn't do "dual assignment" and so come out right, consistently:

?-
A=array(_,_,_,_,_),
forall(
   between(1,5,Index),
   nb_setarg(Index, A, bar)).
A = array(bar, bar, bar, bar, bar).
?-
functor(A, array, 5),
  forall(
     between(1,5,Index),
     nb_setarg(Index, A, bar)).
A = array(bar, bar, bar, bar, bar).

Basically, do not backtrack to before where you started using `nb_*` and only use the `nb_*` predicates on the same location.