Did you know ... Search Documentation:
Predicate once/1
Availability:built-in
Source[ISO]once(:Goal)
Make a possibly nondet goal semidet, i.e., succeed at most once. Defined as: 
once(Goal) :-
    call(Goal), !.

once/1 can in many cases be replaced with ->/2. The only difference is how the cut behaves (see !/0). The following two clauses below are identical. Be careful about the interaction with ;/2. The library(apply_macros) library defines an inline expansion of once/1, mapping it to (Goal->true;fail). Using the full if-then-else constructs prevents its semantics from being changed when embedded in a ;/2 disjunction. 

1) a :- once((b, c)), d.
2) a :- b, c -> d.
Tags are associated to your profile if you are logged in|Report abuse
Tags:
  • doc-needs-help
  • limit-solutions
LogicalCaptain said (2020-05-05T15:09:40):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

"once should be deprecated"

https://swi-prolog.discourse.group/t/once-1-should-be-deprecated/3874

Personal opinion

Definitely prefer once/1 over ->/2.

It makes the intent clear and, unlike ->/2, is actually readable.

Don't get confused

Note that this is absolutely not the same as using "cut":

With

foo(A,B) :- member(A-B,[a-1,b-2,c-3,a-4]).
foo(A,B) :- member(A-B,[d-5,e-6,a-7,f-8]).

we have:

?- foo(a,B).
B = 1 ;
B = 4 ;
B = 7 ;
false.

Once-ify the first clause:

foo(A,B) :- once(member(A-B,[a-1,b-2,c-3,a-4])).
foo(A,B) :- member(A-B,[d-5,e-6,a-7,f-8]).

Then:

?- foo(a,B).
B = 1 ;
B = 7 ;
false.

But if you cut at the end of the first clause:

foo(A,B) :- member(A-B,[a-1,b-2,c-3,a-4]),!.
foo(A,B) :- member(A-B,[d-5,e-6,a-7,f-8]).

You get:

?- foo(a,B).
B = 1.

Where is twice/1 ?

If there is a once/1, there should probably be a twice/1 etc.

And there is: limit/2 from library(solution_sequences)