Did you know ... Search Documentation:
Predicate =../2
Availability:built-in
[ISO]?Term =.. ?List
List is a list whose head is the functor of Term and the remaining arguments are the arguments of the term. Either side of the predicate may be a variable, but not both. This predicate is called‘Univ’. 
?- foo(hello, X) =.. List.
List = [foo, hello, X]

?- Term =.. [baz, foo(1)].
Term = baz(foo(1))

SWI-Prolog also supports terms with arity 0, as in a() (see section 5). Such terms must be processed using compound_name_arguments/3. This predicate raises a domain error as shown below. See also functor/3. 

?- a() =.. L.
ERROR: Domain error: `compound_non_zero_arity' expected, found `a()'

Examples

Convert a CSV with column names to JSON

Convert a CSV with column names to JSON

With the help of library(csv) and library(http/json), we read a CSV file and use the column names in the first row to emit JSON.

For this example, we use the file weather.csv:

city,temp_lo,temp_hi,prcp,date
San Francisco,46,50,0.25,1994-11-27
San Francisco,43,57,0,1994-11-29
Hayward,37,54,,1994-11-29

The script csv_to_json.pl reads the CSV from standard input or from the file provided as the first argument of the script. It converts the contents to a list of dicts, then writes this as JSON to standard output:

:- initialization(main, main).

:- use_module(library(csv)).
:- use_module(library(http/json)).

main :-
    (   current_prolog_flag(argv, [CSV_file|_])
    ->  csv_read_file(CSV_file, CSV, [])
    ;   csv_read_stream(current_input, CSV, [])
    ),
    CSV = [Colnames|Rows],
    Colnames =.. [row|Names],
    maplist(row_dict(Names), Rows, Dicts),
    json_write_dict(current_output, Dicts, [null('')]).

row_dict(Names, Row, Dict) :-
    Row =.. [row|Fields],
    pairs_keys_values(Data, Names, Fields),
    dict_create(Dict, _, Data).

The null('') option to json_write_dict/3 is necessary to convert the empty "prcp" field in the last row to a missing value represented as null in the JSON output.

This is how we can use it to convert weather.csv to JSON:

$ swipl csv_to_json.pl weather.csv
[
  {
    "city":"San Francisco",
    "date":"1994-11-27",
    "prcp":0.25,
    "temp_hi":50,
    "temp_lo":46
  },
  {
    "city":"San Francisco",
    "date":"1994-11-29",
    "prcp":0,
    "temp_hi":57,
    "temp_lo":43
  },
  {
    "city":"Hayward",
    "date":"1994-11-29",
    "prcp":null,
    "temp_hi":54,
    "temp_lo":37
  }
]
Tags are associated to your profile if you are logged in|Report abuse
Tags:
  • destructuring_a_term
  • taking_apart_a_term
  • univ
LogicalCaptain said (2020-05-14T12:28:41):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

A bit surprising perhaps

% works for atoms and strings

?- atom =.. X.
X = [atom].

?- "atom" =.. X.
X = ["atom"].

% works for numbers

?- 3.4 =.. X.
X = [3.4].

?- 3r4 =.. X.
X = [3r4].

?- 3 =.. X.
X = [3].

Overview table

This page provides a short overview of the "analysis/construction" predicates.

From O'Keefe's "The Craft of Prolog" (MIT Press, 1990), p. 145

The first is the meta-logical operations functor/3 and arg/3, particularly the latter. A word of warning here: it is almost always a bad idea to use =../2. Do not use =../2 to locate a particular argument of some term.

For example, instead of

Term =.. [_F,_,ArgTwo|_]

you should write

arg(2, Term, ArgTwo)

You will find it easier to get the explicit number "2" right than to write the correct number of "don't care" variables in the call to =../2.

Other people reading your program will find the call to arg/3 a much clearer expression of your intent. Your program will also be more efficient. Even if you need to locate several arguments of a term, it is clearer and more efficient to write

arg(1, Term, First),
arg(3, Term, Third),
arg(4, Term, Fourth)

than to write

Term =.. [_,First,_,Third,Fourth|_]

Do not use '=..'/2 when you know the functor. (That is, when you know both the function symbol and the arity.)

For example, one Prolog programmer actually wrote the following code:

add_date(OldItem, Date, NewItem) : -
   OldItem =.. [item, Type, Ship, Serial],
   NewItem =.. [item,Type,Ship,Serial,Date].

This could have been expressed more clearly and more efficiently as

add_date(OldItem, Date, NewItem) : -
   OldItem = item(Type,Ship,Serial),
   NewItem = item(Type,Ship,Serial,Date).

or, even better, as

add_date(item(Type,Ship,Serial),Date,item(Type,Ship,Serial,Date)).